а что там со службой СОС?

' // ========================================================================
' // CreateSmsMessage.vbs
' // ------------------------------------------------------------------------
' // This VBScript sample demonstrate how to create a new sms message using
' // the ActiveXperts SMS Messaging Server API.
' // The samples makes use of three objects of the SMS Messaging Server API:
' //   1) AxSmsServer.MessageDB - represents the Message Database
' //   2) AxSmsServer.Message   - a single message, i.e. a single record in the 
' //                              Message Database 
' //   3) AxSmsServer.Constants - collection of constant values
' // For a full explanation of the SMS Messaging Server API, please read the 
' // online manual at www.activexperts.com/asmssrvr/help
' // ========================================================================

Option Explicit

Dim g_objMessageDB, g_objConstants
Dim numRecordID, strRecipient 

' Create global objects
Set g_objMessageDB = CreateObject( "AxSmsServer.MessageDB" ) 
Set g_objConstants = CreateObject( "AxSmsServer.Constants" ) 

' Open the Database
g_objMessageDB.Open
PrintResult( "Open" )
If( g_objMessageDB.LastError <> 0 ) Then
   WScript.Quit
End If

Do
   strRecipient = inputbox( "Please enter the recipient's mobile number below", "Enter Mobile Number", "+31625044454" )
Loop until strRecipient <> ""

' Create new e-mail message
numRecordID = CreateSmsMessage( strRecipient )
If( numRecordID > 0 ) Then
   PrintMessage( numRecordID )
End If

' Close the database
g_objMessageDB.Close

WScript.Echo "Ready."

 

' /////////////////////////////////////////////////////////////////////////////////////

Function CreateSmsMessage( strRecipient )

   Dim objMessage

   ' Create new message in the Message Database
   Set objMessage   = g_objMessageDB.Create
   PrintResult( "Create" )
   If( g_objMessageDB.LastError <> 0 ) Then
      CreateSmsMessage = 0
      Exit Function
   End If  
  
   WScript.Echo "Message successfully created, recordID: " & objMessage.ID

   objMessage.Direction    = g_objConstants.MESSAGEDIRECTION_OUT
   objMessage.Type         = g_objConstants.MESSAGETYPE_SMS
   objMessage.Status       = g_objConstants.MESSAGESTATUS_PENDING
   objMessage.ChannelID    = 0  ' First available SMS channel
   objMessage.ScheduledTime = "" ' To indicate immediate schedule. 
                                ' To schedule 1 day and 2 hours in advance, specify "+1d2h0m"
                                ' To schedule on specific date/time, specify 12/25/2005 07:30

   objMessage.Recipient    = strRecipient
   objMessage.Body         = "SMS Messaging Server - Test SMS"

   ' Save the new values that were just assigned
   g_objMessageDB.Save( objMessage )
   PrintResult( "Save" )
   If( g_objMessageDB.LastError <> 0 ) Then
      CreateSmsMessage = 0
      Exit Function
   End If

   CreateSmsMessage = objMessage.ID

End Function


' /////////////////////////////////////////////////////////////////////////////////////

Sub PrintMessage( numID )
   Dim objMessage

   Set objMessage = g_objMessageDB.Load( numID )
   PrintResult( "Load" )
   If( g_objMessageDB.lastError <> 0 ) Then
      WScript.Echo "Failed to load message " & numID
      Exit Sub 
   End If

   WScript.Echo " Message # " & objMessage.ID
   WScript.Echo "  Direction: " & objMessage.Direction & " (" & g_objMessageDB.GetDirectionDescription( objMessage.Direction ) & ")"
   WScript.Echo "  Type: " & objMessage.Type & " (" & g_objMessageDB.GetTypeDescription( objMessage.Type ) & ")"
   WScript.Echo "  Status: " & objMessage.Status & " (" & g_objMessageDB.GetStatusDescription( objMessage.Status ) & ")"
   WScript.Echo "  StatusDetails: " & objMessage.StatusDetails & " (" & g_objMessageDB.GetStatusDetailsDescription( objMessage.StatusDetails ) & ")"
   WScript.Echo "  ChannelID: " & objMessage.ChannelID
   WScript.Echo "  MessageReference: " & objMessage.MessageReference
   WScript.Echo "  ScheduledTime: " & objMessage.GetScheduledTimeString()
   WScript.Echo "  LastUpdate: " & objMessage.GetLastUpdateString()
   WScript.Echo "  Sender: " & objMessage.Sender
   WScript.Echo "  Recipient: " & objMessage.Recipient
   WScript.Echo "  Subject: " & objMessage.Subject
   WScript.Echo "  Body: " & objMessage.Body
   WScript.Echo "  Trace: " & objMessage.Trace
End Sub

' /////////////////////////////////////////////////////////////////////////////////////

Sub PrintResult( strFunction )
'  NOTE: For a complete list of error codes, please visit http://www.activexperts.com/support/errorcodes
   WScript.Echo strFunction & ", result: " & g_objMessageDB.LastError & " (" & g_objMessageDB.GetErrorDescription( g_objMessageDB.LastError ) & ")"
End Sub